# Maintainer: David Young <david@federated.computer>

pkgname=federated-calendar
pkgver=52.alpha.r6135.ga818b79c
pkgrel=1
pkgdesc="Calendar for Federated Computer Cores, based on GNOME Calendar"
arch=(x86_64)
url="https://gitea.federated.computer/Federated_Computer/federated-calendar"
license=(GPL-3.0-or-later)
depends=(
  dconf
  evolution-data-server
  fribidi
  geoclue
  glib2
  glibc
  graphene
  gsettings-desktop-schemas
  gtk4
  hicolor-icon-theme
  libadwaita
  libedataserverui4
  libgcc
  libgweather-4
  libical
  libsoup3
  pango
)
makedepends=(
  git
  glib2-devel
  meson
)
source=("git+$url.git")
b2sums=('SKIP')

pkgver() {
  cd $pkgname
  local version
  version=$(sed -n "s/^ *version: '\(.*\)',$/\1/p" meson.build)
  printf "%s.r%s.g%s" "$version" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}
